ACTOR Panzerschreck : NaziWeapon 15013
{
	//$Category Weapons (Wolf3D)
	//$Title (7) Panzerschreck
	//$Color 14
	Weapon.SlotNumber 7
	Weapon.SelectionOrder 10000
	Inventory.PickupMessage "You got the Panzerschreck!"
	Tag "Panzerschreck"
	Weapon.AmmoType "PanzerschreckLoaded"
	Weapon.AmmoUse 1
	Weapon.AmmoType2 "PanzerAmmo"
	Weapon.AmmoGive2 1
	Weapon.AmmoUse2 1
	Radius 18
	Height 12
	+WEAPON.NOAUTOFIRE
	Scale .7
	States
	{
	Deselect:
		PANZ A 1 A_Lower
		Loop
	Select:
		PANZ A 1 A_Raise
		Loop
	Ready:
		PANZ A 0 A_JumpIfInventory("PanzerschreckLoaded",0,2)
		PANZ A 0 A_JumpIfInventory("PanzerAmmo",1,2)
		PANZ A 1 A_WeaponReady
		Loop
		PANZ A 1 A_WeaponReady(WRF_ALLOWRELOAD)
		Loop
	Fire:
		PANZ A 0 A_JumpIfInventory("PanzerschreckLoaded",1,1)
		Goto Dryfire
		PANZ A 0 A_PlaySound("panzer/fire",CHAN_WEAPON)
		PANZ A 0 A_GunFlash
		PANZ A 2 Bright A_FireCustomMissile("PanzerRocket",0,1,12,0)
		PANZ A 1 Offset(6,34)
		PANZ A 1 Offset(14,36)
		PANZ A 1 Offset(24,39)
		PANZ A 1 Offset(28,43)
		PANZ A 1 Offset(31,48)
		PANZ A 1 Offset(27,44)
		PANZ A 1 Offset(23,40)
		PANZ A 1 Offset(18,36)
		PANZ A 1 Offset(12,34)
		PANZ A 1 Offset(6,32)
		PANZ A 1 Offset(3,30)
		PANZ A 1 Offset(1,29)
		PANZ A 1 Offset(-2,30)
		PANZ A 1 Offset(-1,32)
		TNT1 A 0 A_CheckReload
		Goto Ready
	Reload:
		PANZ A 1 Offset(1,33) A_PlaySound("panzer/load",CHAN_WEAPON)
		PANZ A 1 Offset(2,34)
		PANZ A 1 Offset(3,35)
		PANZ A 1 Offset(4,36)
		PANZ A 1 Offset(4,43)
		PANZ A 1 Offset(4,50)
		PANZ A 1 Offset(5,58)
		PANZ A 1 Offset(5,67)
		PANZ A 1 Offset(5,71)
		PANZ A 1 Offset(5,77)
		PANZ A 1 Offset(4,83)
		PANZ A 1 Offset(3,89)
		PANZ A 1 Offset(3,94)
		PANZ A 1 Offset(2,100)
		PANZ A 1 Offset(2,102)
		PANZ A 1 Offset(1,104)
		PANZ A 1 Offset(1,106)
		PANZ A 1 Offset(-1,108)
		PANZ A 1 Offset(-3,112)
		PANZ A 1 Offset(-5,116)
		PANZ A 1 Offset(-7,120)
		PANZ A 1 Offset(-10,124)
		PANZ A 1 Offset(-14,126)
		PANZ A 1 Offset(-18,128)
		PANZ A 0 A_TakeInventory("PanzerAmmo",1)
		PANZ A 1 Offset(-21,129) A_GiveInventory("PanzerschreckLoaded")
		PANZ A 1 Offset(-24,130)
		PANZ A 1 Offset(-27,131)
		PANZ A 1 Offset(-28,130)
		PANZ A 1 Offset(-26,128)
		PANZ A 1 Offset(-22,124)
		PANZ A 1 Offset(-21,112)
		PANZ A 1 Offset(-20,108)
		PANZ A 1 Offset(-19,98)
		PANZ A 1 Offset(-18,88)
		PANZ A 1 Offset(-17,78)
		PANZ A 1 Offset(-16,68)
		PANZ A 1 Offset(-15,57)
		PANZ A 1 Offset(-14,46)
		PANZ A 1 Offset(-12,42)
		PANZ A 1 Offset(-11,38)
		PANZ A 1 Offset(-8,35)
		PANZ A 1 Offset(-6,32)
		PANZ A 1 Offset(-2,28)
		PANZ A 1 Offset(1,27)
		PANZ A 1 Offset(-1,29)
		Goto Ready
	Spawn:
		PANP A -1
		Loop
	}
}

ACTOR PanzerschreckLoaded : Ammo
{
	+IGNORESKILL
	Tag "Loaded"
	Inventory.Icon PANZ01
}

ACTOR PanzerRocket
{
	Radius 5
	Height 6
	Speed 70
	PROJECTILE
	-NOTELEPORT
	Damage (2500)
	Decal Scorch
	Obituary "%o notices %k's rocket speeding towards %h."
	ProjectileKickback 25000
	States
	{
	Spawn:
		MNSS A 1 BRIGHT LIGHT(BOAFLMW2) NODELAY A_PlaySound("panzer/fly",CHAN_VOICE,1.0,1)
		MNSS A 1 BRIGHT LIGHT(BOAFLMW2) A_SpawnItemEx("RocketFlame",random(-1,1),0,random(-1,1))
		Wait
	Death:
		EXP1 A 0 A_SetScale(1.25,1.25)
		EXP1 A 0 A_AlertMonsters
		EXP1 A 0 A_PlaySound("panzer/explode",CHAN_VOICE,1.0,0,ATTN_NONE)
		EXP1 A 0 A_Explode(192)
		EXP1 A 2 BRIGHT LIGHT(BOAFLMW2) A_Quake(9,15,0,1024,"")
		EXP1 BCDEFGHIJKLMN 2 BRIGHT LIGHT(BOAFLMW2)
		Stop
	}
}

ACTOR PanzerSpawner replaces BFG9000
{
	States
	{
	Spawn:
		TNT1 A 0 NODELAY A_SpawnItemEx("Panzerschreck",0,0,0,velx,vely,velz)
		TNT1 AAAA 0 A_SpawnItemEx("PanzerAmmo",frandom(-16,16),frandom(-16,16),0,velx,vely,velz,0,SXF_NOCHECKPOSITION)
		Stop
	}
}