Actor SteamSpawner : SwitchableDecoration 16649
{
	//$Category Special Effects (Wolf3D)
	//$Title Steam Spawner (arg1 dir 0up1down2for, arg2 burstbool, arg3 freq)
	//$Color 12
	Height 2
	Radius 1
	Mass 0
	+NoBlockMap
	+NoGravity
	+NoInteraction
	+ClientSideOnly
	States
	{
	Spawn:
	Active:
		TNT1 A 0
		TNT1 A 0 A_JumpIf(Args[0] == 1, "Down")
		TNT1 A 0 A_JumpIf(Args[0] > 1, "Forward")
		TNT1 A 0 A_JumpIf(Args[1] > 0, "UpBurst")
		TNT1 A 0 A_JumpIf(Args[3] > 0, 2)
		TNT1 A 0 A_PlaySound("Steam/Loop",7,1,1)
		TNT1 A 1 A_SpawnItemEx("SteamParticle", 0, 0, 1, (0.1)*Random(0, 4), 0, (0.1)*Random(35, 40), Random(0, 360), 128)
		Loop
	Down:
		TNT1 A 0 A_JumpIf(Args[1] > 0, "DownBurst")
		TNT1 A 0 A_JumpIf(Args[3] > 0, 2)
		TNT1 A 0 A_PlaySound("Steam/Loop",7,1,1)
		TNT1 A 1 A_SpawnItemEx("SteamParticle", 0, 0, 0, (0.1)*Random(0, 4), 0, (-0.1)*Random(35, 40), Random(0, 360), 128)
		Loop
	Forward:
		TNT1 A 0 A_JumpIf(Args[1] > 0, "ForwardBurst")
		TNT1 A 0 A_JumpIf(Args[3] > 0, 2)
		TNT1 A 0 A_PlaySound("Steam/Loop",7,1,1)
		TNT1 A 1 A_SpawnItemEx("SteamParticle", 0, 0, 0, (0.1)*Random(35, 40), 0, (0.1)*Random(-5, 5), Random(-8, 8), 128)
		Loop
	UpBurst:
		TNT1 A 1 A_Jump(Args[2]/16, 1)
		Loop
		TNT1 A 0 A_JumpIf(Args[3] > 0, 2)
		TNT1 A 0 A_PlaySound("Steam/Fire",7,1,1)
		TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 1 A_SpawnItemEx("SteamParticle", 0, 0, 1, (0.1)*Random(0, 4), 0, (0.1)*Random(35, 40), Random(0, 360), 128)
		Loop
	DownBurst:
		TNT1 A 1 A_Jump(Args[2]/16, 1)
		Loop
		TNT1 A 0 A_JumpIf(Args[3] > 0, 2)
		TNT1 A 0 A_PlaySound("Steam/Fire",7,1,1)
		TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 1 A_SpawnItemEx("SteamParticle", 0, 0, 0, (0.1)*Random(0, 4), 0, (-0.1)*Random(35, 40), Random(0, 360), 128)
		Loop
	ForwardBurst:
		TNT1 A 1 A_Jump(Args[2]/16, 1)
		Loop
		TNT1 A 0 A_JumpIf(Args[3] > 0, 2)
		TNT1 A 0 A_PlaySound("Steam/Fire",7,1,1)
		TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 1 A_SpawnItemEx("SteamParticle", 0, 0, 0, (0.1)*Random(35, 40), 0, (0.1)*Random(-5, 5), Random(-8, 8), 128)
		Loop
	Inactive:
		TNT1 A -1 A_StopSound(7)
		Stop
	}
}

Actor SteamParticle
{
	Height 1
	Radius 1
	+Missile
	+NoGravity
	+NoBlockMap
	+DONTSPLASH
	RenderStyle Add
	Scale 0.4
	Alpha 0.65
	States
	{
	Spawn:
		STEM ABCDEFGHIJKL 2 NODELAY A_FadeOut(0.05)
		Stop
	}
}