//Player
Actor BoAPlayer : PlayerPawn
{
	Species "Player"
	+THRUSPECIES
	player.invulnerabilitymode "reflective"
	player.startitem "KnifeSilent"
	player.startitem "TrenchShotgunLoaded",8
	player.startitem "Browning5Loaded",4
	player.startitem "MP40Loaded",32
	player.startitem "G43Loaded",10
	player.startitem "Walther9mmLoaded",8
	player.startitem "Luger9mmLoaded",8
	player.startitem "StenLoaded",32
	player.startitem "Kar98kLoaded",5
	player.startitem "PyrolightLoaded",25
	player.startitem "PanzerschreckLoaded"
	player.startitem "GrenadePickup"
	Player.ViewHeight 56
	Player.AttackZOffset 18
	Player.DisplayName "William Blazkowicz"
	Player.SideMove 1.0,0.5
	Player.ForwardMove 1.0,0.5
	Scale 1.2
	States
	{
	Spawn:
		WEAS A 0 NODELAY A_JumpIf(waterlevel<3,2)
		WEAS A 0 A_SpawnItemEx("Bubble",random(4,8),0,random(48,52),0,0,random(1,3),random(0,360),SXF_TRANSFERTRANSLATION,random(4,8))
		WEAS A 7
		Loop
	See:
		WEAS A 7
		WEAS A 0 A_JumpIf(waterlevel<3,2)
		WEAS A 0 A_SpawnItemEx("Bubble",random(4,8),0,random(48,52),0,0,random(1,3),random(0,360),SXF_TRANSFERTRANSLATION,random(4,8))
		WEAS B 7 A_CheckFloor("Step1")
	Otherleg:
		WEAS C 7
		WEAS C 0 A_JumpIf(waterlevel<3,2)
		WEAS C 0 A_SpawnItemEx("Bubble",random(4,8),0,random(48,52),0,0,random(1,3),random(0,360),SXF_TRANSFERTRANSLATION,random(4,8))
		WEAS D 7 A_CheckFloor("Step2")
		Goto See
	Step1:
		WEAS B 7 A_SpawnItemEx("PlayerStep", 0.0, 0.0, 11.1, 0.0, 0.0, 0.0, 0.0, SXF_NoCheckPosition | 128)
		Goto Otherleg
	Step2:
		WEAS D 7 A_SpawnItemEx("PlayerStep", 0.0, 0.0, 11.1, 0.0, 0.0, 0.0, 0.0, SXF_NoCheckPosition | 128)
		Goto See
	Pain:
		WEAS G 0 A_JumpIf(waterlevel<3,2)
		WEAS G 0 A_SpawnItemEx("Bubble",random(4,8),0,random(48,52),0,0,random(1,3),random(0,360),SXF_TRANSFERTRANSLATION,random(4,8))
		WEAS G 3 A_Pain
		Goto Spawn
	Missile:
		WEAS E 12
		Goto Spawn
	Melee:
		WEAS F 6 BRIGHT
		Goto Missile
	Death:
		WEAS H 0 A_JumpIf(waterlevel<3,2)
		WEAS H 0 A_SpawnItemEx("Bubble",random(4,8),0,random(48,52),0,0,random(1,3),random(0,360),SXF_TRANSFERTRANSLATION,random(4,8))
		WEAS H 5 A_PlayerScream
		WEAS I 5
		WEAS J 5 A_NoBlocking
		WEAS K 5
		WEAS L -1
		Stop
	Death.Fire:
		BURN A 5 BRIGHT LIGHT(ITBURNS1)
		BURN BC 5 BRIGHT LIGHT(ITBURNS1)
		BURN D 5 BRIGHT LIGHT(ITBURNS1) A_PlaySound("death/burning")
		BURN E 5 BRIGHT LIGHT(ITBURNS1)
		BURN FGHIJ 5 BRIGHT LIGHT(ITBURNS2)
		BURN KLMN 5 BRIGHT LIGHT(ITBURNS3)
		BURN O 5 BRIGHT LIGHT(ITBURNS3) A_NoBlocking
		BURN PQR 5 BRIGHT LIGHT(ITBURNS2)
		BURN STU 5 BRIGHT LIGHT(ITBURNS1)
		BURN V -1
		Stop
	}
}

ACTOR PlayerStep
{
	Radius 32
	Height 55
	Gravity 10
	//Mass 0
	+CORPSE
	+NOCLIP
	States
	{
	Spawn:
		TNT1 A 3
		Stop
	Crash:
		TNT1 A 1
		Stop
	}
}